#!/bin/csh -f

set version = 1.3.6

cat << DESC_END
-----------------------------------------------
 GRAPE software package back up program
 usage: bakup [-f|--full]
-----------------------------------------------
DESC_END

cd doc
./genreadme 00readme-j.template > 00readme-j
./genreadme 00readme.template > 00readme
cd ..

./script/clean

set basicfiles = './00readme ./00readme-j \
    ./{gdr,g9,g7,g6bx,g6a,pg5,hibutil,driver}/\
    ./init\
    ./lib\
    ./include\
    ./doc/{Makefile*,*.{pdf,tex,obj,jpg,sty,template},genreadme,00*}\
    ./script\
    ./tmp/dontremoveme\
    ./sample/s8/\
    ./sample/s8f/\
    ./sample/s9/\
    ./sample/direct/{Makefile*,*.{h,c,csh},snapshots,00*}\
    ./sample/directf/{Makefile*,*.{h,c,F,f,inc},00*}\
    ./sample/vtc/{Makefile*,*.{h,c,csh,awk,pl,gp,table},00README,00*}\
    ./sample/pairwise'

set ttffiles = ./ttf
set cudafiles = ./cuda

LABEL_ROOTNAME:

set rootname = grapepkg${version}
if ("$1" == "-f" || "$1" == "--full") then
  set fullpackage = 1
else
  set fullpackage = 0
endif

echo ''
if ($fullpackage == 1) then
  echo 'making fullpackage including .ttf files for GRAPE-7 model300/600.'
  echo 'package size would be more than 30MB.'
else
  echo 'making default package *WITHOUT* .ttf files for GRAPE-7 model300/600.'
endif
echo ''
echo -n "Specify the root name for the package (default ${rootname}): "
set answer = $<
if (${answer} != '') then
  set rootname = ${answer}
endif
if (-f ${rootname}.tar.gz) then
  echo -n "${rootname}.tar.gz exists. Overwrite? (y/n): "
  set answer = $<
  if (${answer} != 'y') then
    goto LABEL_ROOTNAME
  endif
endif
rm -rf ${rootname}.tar.gz

if ($fullpackage == 1) then
  tar cvfz tmp$$.tar.gz $basicfiles $ttffiles
  tar cvfz tmpcuda$$.tar.gz $basicfiles $cudafiles $ttffiles
else
  tar cvfz tmp$$.tar.gz $basicfiles
  tar cvfz tmpcuda$$.tar.gz $basicfiles $cudafiles
endif

mkdir tmp$$
mkdir tmp$$/${rootname}
cd tmp$$/${rootname}
tar xvfz ../../tmp$$.tar.gz
cd ..
tar cvfz ./${rootname}.tar.gz ./${rootname}
mv ./${rootname}.tar.gz ..
cd ..
/bin/rm -rf tmp$$ tmp$$.tar.gz
echo "Created ./${rootname}.tar.gz"
echo ''

mkdir tmp$$
mkdir tmp$$/${rootname}
cd tmp$$/${rootname}
tar xvfz ../../tmpcuda$$.tar.gz
cd ..
tar cvfz ./${rootname}.tar.gz ./${rootname}
mv ./${rootname}.tar.gz ../${rootname}-with-cudag5g6.tar.gz
cd ..
/bin/rm -rf tmp$$ tmpcuda$$.tar.gz
echo "Created ./${rootname}-with-cudag5g6.tar.gz"
echo ''
